【銀行員・信金職員におすすめ！】個人用マクロブック～導入編～

Sub 全シートA1選択()
    
    '対象のブックを変数に格納
    Dim wb As Workbook
    Set wb = ActiveWorkbook
    
    'マクロ実行時に選択されているシートを変数に格納
    Dim ws対象 As Worksheet
    Set ws対象 = ActiveSheet
    
    'For Each ～ Nextで全シートをループし、A1セルを選択する
    Dim ws As Worksheet
    For Each ws In wb.Worksheets
        ws.Activate
        ws.Range("A1").Select
    Next
    
    'マクロ実行時に選択されているシートに戻る
    ws対象.Select
    
End Sub

Sub 全シートA1選択ズーム100()
    
    '対象のブックを変数に格納
    Dim wb As Workbook
    Set wb = ActiveWorkbook
    
    'マクロ実行時に選択されているシートを変数に格納
    Dim ws対象 As Worksheet
    Set ws対象 = ActiveSheet
    
    'For Each ～ Nextで全シートをループし、A1セルを選択する
    Dim ws As Worksheet
    For Each ws In wb.Worksheets
        ws.Activate
        ActiveWindow.Zoom = 100             'ズームの倍率100％
        ActiveWindow.ScrollRow = 1          'ウィンドウの上部に表示される行の数を設定
        ActiveWindow.ScrollColumn = 1       'ウィンドウ内で左端に表示される列の番号を設定
        ActiveWindow.View = xlNormalView    '標準プレビューモードに設定
        ws.Range("A1").Select
    Next
    
    'マクロ実行時に選択されているシートに戻る
    ws対象.Select
    
End Sub

Sub 自ブックのフォルダを開く()

    CreateObject("WScript.Shell").Run ActiveWorkbook.Path
    
End Sub

Sub YYYYMMDD形式⇒日付型に変換()

    On Error Resume Next
    Dim zセル As Range
    For Each zセル In Selection
        
        'セルの値が数値であるか確認する
        If IsNumeric(zセル.Value) = True Then
            'YYYYMMDD（８文字）であるか確認する
            If Len(zセル.Value) = 8 Then
                '存在する日付か確認する
                If IsDate(Format(CStr(zセル.Value), "####/##/##")) = True Then
                    zセル.Value = Format(CStr(zセル.Value), "####/##/##")
                    '表示形式を設定する
                    zセル.NumberFormatLocal = "yyyy/mm/dd"
                End If
            End If
        End If
    Next
    
End Sub